简单介绍
人物登录脚本即在人物进入游戏时自动执行的脚本，通过此脚本可对人物进
行大量的功能控制。
使用方法 在目录 Envir\\MapQuest_def\\ 中建立文件名为QManage.txt的脚本
按以下格式编写脚本：
=====================================================================
;脚本例子
[@Login]
#IF
checknamelist 会员.txt
#ACT
;人物杀怪经验为10倍
CANGETEXP 1 10
;人物攻击力翻2倍
MULTPOWER 2
;送一个七级神兽
EXECUTE RCALLMOB 神兽 7
#SAY
欢迎进入游戏，你当前登录的是会员号，会员可以得到大量的优待。\\ <关闭/@exit>
注：如该脚本更改后，可不须重启M2使其生效，可用@ReloadManage命令重新加载该脚本。
String.ini
[String]
;夫妻传送命令设置，可更改为自己指定的命令
CMD_RECALLDEAR=RECALLDEAR
;允许夫妻传送命令设置，可更改为自己指定的命令
CMD_ALLOWRECALLDEAR=ALLOWRECALLDEAR
;查询夫妻位置命令
CMD_DEAR=WDEAR
结婚脚本注：强行离婚(指一方不在线或不同意离婚)需要在登录脚本人加入以下命令
(让所有人上线都运行DEARINFO命令即可，否则不接受离婚方或不在线离婚方在强行离
婚后上线仍有结婚字样。
==============================================================
[@Login]
#IF
#ACT
DEARINFO
==============================================================
以上脚在新版本中不再需要
结婚脚本：
[@main]
<求婚/@marry>\\
<离婚/@unmarry>\\
<询问结婚时间/@asktime>\\ <离开/@exit>
[@marry]
求婚者必须是男性且拥有求婚戒指，你准备好求婚了吗？\\ <准备好了/@agree>\\
<下次再来/@exit>\\ \\ <返回/@main>
[@agree]
#if
checkmarryed
#act
break
#say
你都结过婚了，还来注册结婚，想犯重婚罪呀！！！ \\ <返回/@main>
#if
gender man
checkitemw 求婚戒指 1
execheck dir
execheck dir 2
#act
takew 求婚戒指 1
exemarry
break
#if
gender man
checkitemw 求婚戒指 1
execheck dir
#say
你变态呀！！！想搞同性恋！！！
#ACT
BREAK
#if
gender man
execheck dir
execheck dir 2
#say
你没求婚戒指，弄到求婚戒指再来找我吧！！！\\ #ACT
BREAK
#if
gender man
execheck dir
execheck dir 1
#say
你变态呀！！！想搞同性恋！！！
#ACT
BREAK
#if
gender man
checkitemw 求婚戒指 1
#SAY
双方必须面对面才能求婚！！！
#ACT
BREAK
#if
gender man
#say
你没求婚戒指，弄到求婚戒指再来找我吧！！！\\ #ACT
BREAK
#if
gender
#say
只有男性才有求婚的权利！！！
#ACT
BREAK
[@error]
[@StartMarry]
#IF
checkmarryed
#SAY
你都结过婚了，还来注册结婚，想犯重婚罪呀！！！ \\ <返回/@main>
#ACT
break
#IF
GENDER MAN
#ACT
BREAK
#SAY
婚礼现在正式开始。\\ 你愿意娶对方为妻，并照顾她一生一世吗？\\
<求婚/@RequestMarry>
#IF
GENDER
#ACT
BREAK
#SAY
婚礼现在正式开始。\\ 请耐心等待你心爱的人向你求婚\\ \\
[@RequestMarry]
#IF
checkmarryed
#ACT
break
#SAY
你都结过婚了，还来注册结婚，想犯重婚罪呀！！！ \\ <返回/@main>
#IF
#ACT
EXEMARRY REQUESTMARRY
[@WateMarry]
你已向对方求婚，请耐心等待对方的答复。
[@RevMarry]
#IF
checkmarryed
#ACT
break
#SAY
你都结过婚了，还来注册结婚，想犯重婚罪呀！！！ \\ <返回/@main>
#IF
#SAY
对方向你求婚，你是否答应嫁给他？ \\ <我愿意/@ResposeMarry>
<我不愿意/@ResposeMarryFail>
[@ResposeMarry]
#IF
checkmarryed
#ACT
break
#SAY
你都结过婚了，还来注册结婚，想犯重婚罪呀！！！ \\ <返回/@main>
#IF
#ACT
EXEMARRY RESPONSEMARRY OK
[@ResposeMarryFail]
#IF
checkmarryed
#ACT
break
#SAY
你都结过婚了，还来注册结婚，想犯重婚罪呀！！！ \\ <返回/@main>
#IF
#ACT
EXEMARRY RESPONSEMARRY FAIL
[@EndMarry]
你们二个已经成为了一对全法夫妻了。\\ <关闭/@exit>
[@EndMarryFail]
结婚失败！\\ <关闭/@exit>
[@MarryDirErr]
对方没站好位置
[@MarryCheckDir]
请站好位置\\\\
[@HumanTypeErr]
你变态呀，既然选择一个非人类作为结婚对象。
[@MarrySexErr]
你变态呀，既然同性恋。
;==========================================
离婚开始
[@unmarry]
#IF
checkmarryed
#ACT
exeunmarry
#Elsesay
你都没结婚离什么婚？？\\ <返回/@main>
;=======================================================
;双方离婚时没面对面站好显示的信息
[@UnMarryCheckDir]
要离婚是吧？离婚是二个人的事，必须二个人对面对站好位置，如果人来不了
你只能选择强行离婚姻了。\\ <我要强行离婚/@fUnMarry>\\
<返回/@main>
;=======================================================
;对面位置不是人物时显示的信息
[@UnMarryTypeErr]
你对面站了个什么东西，怎么不太象人来的。\\ <返回/@main>
;=======================================================
;开始离婚程序后，双方显示的信息
[@StartUnMarry]
#IF
gender man
#ACT
BREAK
#SAY
是否确定真的要与你共事多年的妻子离婚吗？\\ <确定/@RequestUnMarry>
#IF
gender
#SAY
你的老公现在向我请求离婚，是不是愿意协议离婚？ \\ <确定/@RequestUnMarry>
#ACT
break
;=======================================================
;发出离婚请求
[@RequestUnMarry]
#IF
checkmarryed
#ACT
exeunmarry requestunmarry
;=======================================================
;回应离婚请求
[@ResposeUnMarry]
#IF
checkmarryed
#ACT
exeunmarry responseunmarry
;===============================================
;请求离婚后显示的信息
[@WateUnMarry]
你已向对方发出离婚请求，请耐心等待对方的答复。
;===============================================
;请求离婚后对方显示的信息
[@RevUnMarry]
对方向你离婚请求，你是否答应离婚？ \\ <我愿意/@RequestUnMarry>
<返回/@main>
;===============================================
;没结过婚的人点离婚后出的提示信息
[@ExeMarryFail]
你都没结过婚，跑来做什么？ \\ [返回/@main]
;==============================================
;强行离婚
[@fUnMarry]
#IF
checkitem 金条 1
checkmarryed
#ACT
take 金条 1
exeunmarry requestunmarry force
#ElseSay
要收一根金条的手续费，你没有金条，我不能让你离婚。<确定/@exit>
;==============================================
;离婚完成后的提示信息
[@UnMarryEnd]
呵呵，你已经脱离苦海了！！！ \\ <退出/@exit>
[@asktime]
你调查结婚时间的请求已发出，请稍后。<确定/@exit>
相关部份参数设置:
!setup.txt
[Config]
;出师等级
MasterOKLevel=40
;出师得到的声望点数
MasterCreditPoint=1
;出师是否可以得到属性点数，1为是，0为否
CanGetMasterPoint=1
;出师得到的属性点数
MasterBonusPoint=100
;转生得到的属性点数，此点数为默认点数，以脚本控制为准，
如果脚本没指定点数，则使用此点数
ReNewPoint=100
;武士属性点数分配比例
BonusofWarrDC=17
BonusofWarrMC=20
BonusofWarrSC=20
BonusofWarrAC=20
BonusofWarrMAC=20
BonusofWarrHP=1
BonusofWarrMP=3
BonusofWarrHit=20
BonusofWarrSpeed=35
;法师属性点数分配比例
BonusofWizardDC=17
BonusofWizardMC=25
BonusofWizardSC=30
BonusofWizardAC=20
BonusofWizardMAC=15
BonusofWizardHP=2
BonusofWizardMP=1
BonusofWizardHit=25
BonusofWizardSpeed=35
;道士属性点数分配比例
BonusofTaosDC=20
BonusofTaosMC=30
BonusofTaosSC=17
BonusofTaosAC=20
BonusofTaosMAC=15
BonusofTaosHP=2
BonusofTaosMP=1
BonusofTaosHit=30
BonusofTaosSpeed=30
String.ini
[String]
;师徒传送命令设置，可更改为自己指定的命令
CMD_RECALLMASTER=RECALLMASTER
;允许师徒传送命令设置，可更改为自己指定的命令
CMD_ALLOWRECALLMASTER=ALLOWRECALLMASTER
;查询师徒位置命令
CMD_MASTER=MASTER
脚本样例
本脚本未加条件检查，实际使用时请自行按自己要求加上条件检查。
[@remain]
<我要拜师/@master>\\<解除师徒关系/@unmaster> \\ <返回/@main>
;==============================================
[@master]
#IF
checkismaster
#ACT
break
#SAY
已经收了一个徒弟！！！ \\ <返回/@remain>
#IF
checkmaster
#ACT
break
#SAY
你已经拜师了！！！ \\ <返回/@remain>
#IF
CheckLevel 40
#ACT
break
#Say
你都到收徒级别了还要来拜师！！！\\ <返回/@remain>
#IF
EXECHECK DIR
execheck postlevel 29
#ACT
exemaster
BREAK
#IF
EXECHECK DIR
#ACT
BREAK
#Say
对方必须29级以上才有资格做你的师傅！！！\\ <返回/@remain>
#IF
#ACT
BREAK
#Say
双方必须面对面才可以拜师！\\ <返回/@remain>
[@StartMaster]
#IF
checkmaster
#SAY
你都有师傅了，想背叛师门？ \\ <返回/@remain>
#ACT
break
#IF
checkismaster
#SAY
你都有徒弟了，现在暂时只能收一个徒弟！！！ \\ <返回/@remain>
#ACT
break
#IF
#ACT
#SAY
你确定与对方建立师徒关系？\\ \\
<确定/@RequestMaster>
[@RequestMaster]
#IF
checkmaster
#SAY
你都有师傅了，想背叛师门？ \\ <返回/@remain>
#ACT
break
#IF
checkismaster
#SAY
你都有徒弟了，现在暂时只能收一个徒弟！！！ \\ <返回/@remain>
#ACT
break
#IF
#ACT
EXEMASTER REQUESTMASTER
[@WateMaster]
你已向对方发出请求，请等待对方的答复。
[@RevMaster]
#IF
checkmaster
#SAY
你都有师傅了，想背叛师门？ \\ <返回/@remain>
#ACT
break
#IF
checkismaster
#SAY
你都有徒弟了，现在暂时只能收一个徒弟！！！ \\ <返回/@remain>
#ACT
break
#IF
#SAY
对方向你请求建立师徒关系，你是否答应？ \\ <没问题/@ResposeMaster>
<不想答应/@ResposeMasterFail>
[@ResposeMaster]
#IF
checkmaster
#SAY
你都有师傅了，想背叛师门？ \\ <返回/@remain>
#ACT
break
#IF
checkismaster
#SAY
你都有徒弟了，现在暂时只能收一个徒弟！！！ \\ <返回/@remain>
#ACT
break
#IF
#ACT
EXEMASTER RESPONSEMASTER OK
[@ResposeMasterFail]
#IF
checkmaster
#SAY
你都有师傅了，想背叛师门？ \\ <返回/@remain>
#ACT
break
#IF
checkismaster
#SAY
你都有徒弟了，现在暂时只能收一个徒弟！！！ \\ <返回/@remain>
#ACT
break
#IF
#ACT
EXEMASTER RESPONSEMASTER FAIL
[@EndMaster]
恭喜！你们二个已经建立了师徒关系了。\\ <关闭/@exit>
[@EndMasterFail]
失败！\\ <关闭/@exit>
[@MasterDirErr]
对方没站好位置
[@MasterCheckDir]
师徒必须面对面！！！\\\\
[@HumanTypeErr]
对方有问题
[@unmaster]
#IF
checkismaster
#ACT
EXEUNMASTER
break
#say
已经脱离了师徒关系！！！
#IF
checkmaster
#ACT
EXEUNMASTER
#say
已经脱离了师徒关系！！！
#ELSESAY
晕！！你都没有拜师或收徒！！！
checkjob (Warr, Wizard, Taos) ;测试职业
checkgold (金币数) ;测试金币
checklevel (等级) ;测试等级
checkitem (物品名) (数量) ;测试物品及数量
give gold (金币数) ;给钱
give (物品名) (数量) ;给物及数量
take gold (金币数) ;拿走钱
take (物品名) (数量) ;拿走物及数量
checkpkpoint (pk值) ;测试PK值
checkluckypoint (幸运值) ;幸运值正值为好,负值为差
checkduraeva (物品名) (数值) ;一般测试矿物等物品的品质
checkhum (地图名) (数值) ;测试这个地图的人数
checkmonmap (地图名) (数值) ;测试这个地图的怪物数
map (地图名) ;移动到这个地图
mapmove (地图名) (坐标A) (坐标B) ;移动到这个地图指定坐标
monclear 地图清除
close 关闭对话框
TimeRecall (设定时间值) ;分钟,一般指进入地图时间限制
BreakTimeRecall ;中断设定时间
ExchangeMap (地图名) ;与指定地图里的人交换位置
daytime sunset ;一天时间
checkbaggage ;测试背包满没
small (变量) (数值) ;测试变量是不是小于指定数值
large (变量) (数值) ;测试变量是不是大于指定数值
equal (变量) (数值) ;测试变量是不是等于指定数值
mov (变量) (数值) ;让变量等于指定数值
sum (变量A) (变量B) ;A+B 注意,如果还要家第3个数直接换行写sum (变量C)
注:关于SUM的详解
首先有MOV (变量X) 0 ;(变量X)清0
sum (变量A) (变量B) ;X=A+B
sum (变量C) ;X=X+C
movr (变量) (数值) ;随机把指定数值以下的数(正数)给变量
inc (变量) (数值) ;让变量自动加指定数值到变量
playdice (骰子数) @xxx ;玩骰子,跳转到标签[@xxx]
random (随机数) ;一般用在#IF语句中作为触发#IF机率,有时随机数=并列#IF语
句数用于随机多项选择,既:
#IF RANDOM 3 #SAY() #ELSEACT
#IF RANDOM 3 #SAY() #ELSEACT
#IF RANDOM 3 #SAY() #ELSEACT
Check [条件数] 1 ;测试[条件数]触发与否 1(触发)
SET [条件数] 1 ;设置[条件数]触发
batchDelay (暂停时间) ;一般为1
addbatch (地图名1)
addbatch (地图名2)
addbatch (地图名3)
addbatch (地图名4)
addbatch (地图名5)
batchmove ;一步步到下一个地图直到5
param1 01141 ;01141=(地图名)
param2 10
param3 10
mongen 火焰沃玛2(怪物名) 30 10
;玩骰子脚本解析
#IF
equal p9 1 ;测试 p9是不是等于1
#ACT
goto @cube ;是的,到@cube
BreakTimeRecall (中断设定时间)
break
#IF
equal p9 9 ;测试 p9是不是等于9
#ACT
goto @quit ;是的,到@quit 退出
BreakTimeRecall (中断设定时间)
break
[@main-1]
#IF
#ACT
mov p9 0 ;测试 p9是不是等于0
#SAY
say ;欢迎词
<下一步/@pre_cube>
[@pre_cube]
#IF
checkitem 筹码 1 ;测试有没有筹码
#ACT
mov p9 1 ;有,让p9=1
take 筹码 1 ;给出一个筹码
movr d0 6 ;;随机把6以下的数(正数)给d0
inc d0 1 ;让d0自动加1到d0
playdice 1 @cube ;玩骰子,点击到标签[@cube]
#SAY
正在投骰子. \\ <下一个/@cube>
#ELSESAY
quit
<退出/@Quit>
#ELSEACT
mov p9 9 ;转到标签@quit并让P9等于9
[@Quit]
#IF
#ACT
map B011 ;退出到B011地图
[@cube]
#IF
#SAY
骰子的点数 <$STR(D0)> \\ ;<$STR(D0)>是变量,把D0数值型转字符型
你可以前进 <$STR(D0)> \\ <移动/@next_cube>
[@next_cube]
#IF
equal d0 1 ;如果 d0=1
#ACT
goto @posi1 ;到POSI1
break
#IF
equal d0 2
#ACT
goto @posi2
break
#IF
equal d0 3
#ACT
goto @posi3
break
#IF
equal d0 4
#ACT
goto @posi4
break
#IF
equal d0 5
#ACT
goto @posi5
break
#IF
equal d0 6
#ACT
goto @posi6
break
[@Posi1]
#IF
#ACT
batchDelay 1 ;一般为1(暂停时间)
addbatch B102 ;步进地图名1
batchmove ;移动到最后一个步进地图
[@Posi2]
#IF
#ACT
batchDelay 1
addbatch B102
addbatch B103
batchmove
[@Posi3]
#IF
#ACT
batchDelay 1
addbatch B102
addbatch B103
addbatch B104
batchmove
[@Posi4]
#IF
#ACT
batchDelay 1
addbatch B102
addbatch B103
addbatch B104
addbatch B105
batchmove
[@Posi5]
#IF
#ACT
batchDelay 1
addbatch B102
addbatch B103
addbatch B104
addbatch B105
addbatch B106
batchmove
[@Posi6]
#IF
#ACT
batchDelay 1 ;一般为1(暂停时间)
addbatch B102 ;步进地图名1
addbatch B103 ;步进地图名2
addbatch B104 ;步进地图名3
addbatch B105 ;步进地图名4
addbatch B106 ;步进地图名5
addbatch B107 ;步进地图名6
batchmove ;移动到最后一个步进地图(这里是6)
;结束
SET
语句：
#IF
……
#ACT(SAY)
……
#ELSESAY(ACT) ;ELSE的两句是并列的,都是IF<>(条件)的动作
……
#ELSEACT(SAY)
……
goto (标签名)
break (中断)
\\ ;换行
<xxx/@xxx>
变量:
<$USERNAME> 当前用户名
<$GUILDWARFEE>行会战金币数
<$LORD>沙巴克行会头名
<$OWNERGUILD>沙巴克行会名
<$UPGRADEWEAPONFEE>升级武器价格
<$USERWEAPON> 放在对话框里的武器名字
<$STR(变量)> 把变量转换为字符型
检测性别是否为男: GENDER MAN
检测身上的物品 CHECKITEMW 龙纹剑 1
取下戴在身上的指定物品: TAKEW 金项链 1
取下戴在身上的任何头盔: TAKEW [HELMET]
取下戴在身上的任何项链: TAKEW [NECKLACE]
取下戴在身上的任何戒指: TAKEW [RING]
取下戴在身上的任何手镯: TAKEW [ARMRING]
取下戴在身上的任何武器: TAKEW [WEAPON]
检测刚刚取下的物品是不是某种物品: ISTAKEITEM 骷髅戒指
dayofweek sun 检测星期
mon
tue
wed
thu
fri
sat
更换人物发型脚本.
[@main]
欢迎光临本测试游戏区，本区主要用于测试服务器的新功能。本区只有此一个场景，
大家可尽情测试防外挂及新功能。\\ <换发型/@ChangHair> \\ <关闭/@exit>
[@ChangHair]
#IF
gender man
#ACT
goto @ChangHairMan
#ELSEACT
goto @ChangHairWoman
[@ChangHairMan]
想不想来个光头呀，酷呆了！！！\\ <光头/@hairman0><长头发/@hairman1>\\
<返回/@main>
[@hairman0]
#ACT
EXECUTE CHGHAIR 0
#SAY
呵呵，光头是不是很酷呀！！！ \\ <返回/@ChangHair>
[@hairman1]
#ACT
EXECUTE CHGHAIR 1
#SAY
呵呵，你的发型已经改变了... \\ <返回/@ChangHair>
[@ChangHairWoman]
<短发型/@hairWoman0><长发型/@hairWoman1>\\ <返回/@main>
[@hairWoman0]
#ACT
EXECUTE CHGHAIR 0
#SAY
呵呵，你的发型已经改变了... \\ <返回/@ChangHair>
[@hairWoman1]
#ACT
EXECUTE CHGHAIR 1
#SAY
呵呵，你的发型已经改变了... \\ <返回/@ChangHair>
更换人物性别
[@main]
欢迎光临本测试游戏区，本区主要用于测试服务器的新功能。
本区只有此一个场景，大家可尽情测试防外挂及新功能。\\
<换性别/@ChangGender>\\ <关闭/@exit>
[@ChangGender]
#IF
gender man
#SAY
是不是做猛男没什么意思呀，想不想尝尝做淑女的滋味呀！！！\\
<尝尝/@towoman>\\ <返回/@main>
#ELSESAY
是不是做淑女挺累的，想不想尝尝做猛男的滋味呀！！！\\
<尝尝/@toman>[@toman]
#ACT
EXECUTE CHGENDER 0
#SAY
呵呵，你已经变成一位猛男了。\\ <返回/@ChangGender>
[@towoman]
#ACT
EXECUTE CHGENDER 1
#SAY
呵呵，你已经变成一位淑女了。\\ <返回/@ChangGender>
更换人物职业
[@main]
欢迎光临本测试游戏区，本区主要用于测试服务器的新功能。本区只有此一个场景，
大家可尽情测试防外挂及新功能。\\ <换职业/@ChangJob>\\ <关闭/@exit>
[@ChangJob]
#IF
checkjob warrior
#SAY
是不是做武士不好玩呀，换换别的试试吧！\\
<玩玩法师/@ToWizard><玩玩道士/@Totaos>\\
<返回/@main>
#ACT
break
#IF
checkjob wizard
#SAY
是不是做魔法师不好玩呀，换换别的试试吧！\\
<玩玩武士/@Towarr><玩玩道士/@Totaos>\\
<返回/@main>
#ACT
break
#IF
checkjob taoist
#SAY
是不是做道士不好玩呀，换换别的试试吧！\\
<玩玩武士/@Towarr><玩玩法师/@ToWizard>\\
<返回/@main>
#ACT
break
[@Towarr]
#ACT
EXECUTE CHGJOB 0
#SAY
呵呵，你已经变成一位武士了。\\
<返回/@ChangJob>
[@ToWizard]
#ACT
EXECUTE CHGJOB 1
#SAY
呵呵，你已经变成一位魔法师了。\\
<返回/@ChangJob>
[@Totaos]
#ACT
EXECUTE CHGJOB 2
#SAY
呵呵，你已经变成一位道士了。\\
<返回/@ChangJob>
更换人物名字的色
[@main]
欢迎光临本测试游戏区，本区主要用于测试服务器的新功能。
本区只有此一个场景，大家可尽情测试防外挂及新功能。\\
<换颜色/@ChangColor>\\ <关闭/@exit>
[@ChangColor]
是不是觉得自己名称的颜色太单调了，换换试试！\\
<复原/@Color255><颜色0/@Color0><颜色1/@Color1><颜色2/@Color2><颜色3/@Color3>\\
<返回/@main>
[@Color255]
#ACT
EXECUTE CHGCOLOR 255
#SAY
呵呵，你的颜色已经改变。\\ <返回/@ChangColor>
[@Color0]
#ACT
EXECUTE CHGCOLOR 0
#SAY
呵呵，你的颜色已经改变。\\ <返回/@ChangColor>
[@Color1]
#ACT
EXECUTE CHGCOLOR 1
#SAY
呵呵，你的颜色已经改变。\\ <返回/@ChangColor>
[@Color2]
#ACT
EXECUTE CHGCOLOR 2
#SAY
呵呵，你的颜色已经改变。\\ <返回/@ChangColor>
[@Color3]
#ACT
EXECUTE CHGCOLOR 3
#SAY
呵呵，你的颜色已经改变。\\ <返回/@ChangColor>
装备升级控制
功能：
可指定升级人物身上带的物品属性，所有机率由命令参数决定
（某些属性，有可能使物品变成废品）。
命令格式：
UPGRADEITEM 0 10 3
0 代表物品类型(0 - 8)
10 代表升级成功机率(0-10) 0为成功率高 10为低
3 代表升级属性最高点数
物品类型： 0 盔甲
1 武器
2 照明物（蜡烛）
3 项链
4 头盔
5 右手镯
6 左手镯
7 右戒指
8 右戒指
脚本例子：（此脚本未加任何条件检查，实际使用时自行加上条件检查）
;============================================================
[@UPgradeItem]
<盔甲/@UpItem0> <武器/@UpItem1> <照明物/@UpItem2> <项链/@UpItem3>
<头盔/@UpItem4> <右手镯/@UpItem5> <左手镯/@UpItem6> <右戒指/@UpItem7>
<右戒指/@UpItem8>
[@UpItem0]
#IF
#ACT
UPGRADEITEM 0 10 3
goto @UpOver
[@UpItem1]
#IF
#ACT
UPGRADEITEM 1 10 3
goto @UpOver
[@UpItem2]
#IF
#ACT
UPGRADEITEM 2 10 3
goto @UpOver
[@UpItem3]
#IF
#ACT
UPGRADEITEM 3 10 3
goto @UpOver
[@UpItem4]
#IF
#ACT
UPGRADEITEM 4 10 3
goto @UpOver
[@UpItem5]
#IF
#ACT
UPGRADEITEM 5 10 3
goto @UpOver
[@UpItem6]
#IF
#ACT
UPGRADEITEM 6 10 3
goto @UpOver
[@UpItem7]
#IF
#ACT
UPGRADEITEM 7 10 3
goto @UpOver
[@UpItem8]
#IF
#ACT
UPGRADEITEM 8 10 3
goto @UpOver
[@UpOver]
呵呵，看你的运气了！！！\\ <返回/@main>
装备在线属性调整
功能：
在线超级物品属性调整(调整时物品必须戴在身上)，不同物品属性代码不一样。
命令格式:
@smake 物品代码 属性代码 属性值
使用例子:
制作一个攻 + 10 的武器
@smake 1 0 10
制作一个魔 + 10 的武器
@smake 1 1 10
制作一个道 + 10 的武器
@smake 1 2 10
=========================================================================
物品代码:
0为衣服 1为武器 2为蜡烛 3为项链 4为头盔 5为左手镯 6为右手镯 7为左戒指 8为右戒指
属性代码:
0 - 13(一般属性为 0 - 7 之间，其它代码为一些附加属性)
(1)刀属性代码：
0攻
1魔
2道
3幸运
4诅咒
5准确
6减攻击速度
=========================================================================
项链 3 7 1 不能下 3 7 0能下
3 1 1 魔法恢复10% 敏加1
3 2 1 攻击加1
3 3 1 魔法加1
3 4 1 道术加1
3 5 1 需要攻击力为1 ；3 5 2 需要魔法 3 5 3 需要精神 3 5 4 不能配代
3 6 ? 其3 5 1的数值
其它首饰一样
左手镯 5 0 1 防加1
5 1 1 魔御加1
5 2 1 攻击加1
5 3 1 魔加1
5 4 1 道加1
5 5 1 需要攻击 5 5 2 需要魔法 5 5 3 需要精神 5 5 4 不能配代
5 6 ? ？是（5 5 1 ）需要数值 如：把一个手镯变为需要35魔法的人带，
就要先输入@smake 5 5 2 再输：@smake 5 6 35
5 7 1 不能取下来 5 7 0能取下来， 5 7 2 不能带上去！！
注：不能取下来 571很好，能出租装备啊，想想吧，呵呵
评论