NPC脚本的执行流程主要由以下组成：
每一个NPC脚本都有由一个[@main]脚本标签开始脚本执行，相当于一个MAIN函数头一样，在此脚本下的主要语句有：
#IF
#ACT (#SAY) //ACT与SAY是并列执行的
#ELSEACT (#ELSESAY) //ELSEACT与ELSESAY是并列执行的
#SAY
#ELSESAY
Break //中断脚本流程执行
GOTO @标签名 //跳转到指定标签段
-------------------------------
#IF //假设条件语句，如果的意思
#ACT //如果条件成立就执行
#SAY //如果条件成立就显示，SAY语句作用是在客户端显示对话信息
#ELSEACT //如果条件不成立就执行
#ELSESAY //如果条件不成立就显示，ELSESAY语句作用是在客户端显示对话信息
范例：
[@main]
#IF
checkjob Warr //检测是否是战士职业
#ACT
SENDMSG 5 你的职业是战士
#SAY
你的职业是战士
#ELSEACT
SENDMSG 5 你不是战士职业
#ELSESAY
你不是战士职业
//ACT与SAY是并列执行的
//ELSEACT与ELSESAY是并列执行的
也可以这样：
[@main]
#IF
checkjob Warr //检测是否是战士职业
#ACT
SENDMSG 5 你的职业是战士
#ELSEACT
SENDMSG 5 你不是战士职业
[@main]
#IF
checkjob Warr //检测是否是战士职业
#SAY
你的职业是战士
#ELSESAY
你不是战士职业
-------------------------------
下面来看 Break //中断脚本流程执行功能
很多时候，脚本的某一个功能，都是由很多条件假设构成，当我们要同时检查多个并列的条件时，就需要用到脚本“Break中断”了，当然，如果不用中断写法，肯定就要用到GOTO跳转了，但为了降低资源和优化效率，一般是采用break中断写法，尽量不使用GOTO跳转。
比如：我要检查当前指定脚本的玩家等级是否有50级，是否是女性，是否是战士职业，是否有50个元宝？如何来实现这个功能呢？我们分两种写法来说明Break中断的作用！
范例1：（使用传统的GOTO跳转来实现）
[@传统写法]
#IF
CHECKLEVELEX > 49
#ACT
GOTO @检测性别
#ELSESAY
你的等级不足50级\\
<离开[url=]/@exit[/url]>
[@检测性别]
#IF
gender WOMAN
#ACT
GOTO @检测职业
#ELSESAY
你不是女性玩家\\
<离开[url=]/@exit[/url]>
[@检测职业]
#IF
checkjob Warr
#ACT
GOTO @检测元宝
#ELSESAY
你不是战士职业\\
<离开[url=]/@exit[/url]>
[@检测元宝]
#IF
CHECKGAMEGOLD > 49
#SAY
你满足条件，你的元宝有50个！\
你是女性，50级，战士职业玩家！\
<离开[url=]/@exit[/url]>
#ELSESAY
你的元宝不足50个\\
<离开[url=]/@exit[/url]>
范例2：（使用Break中断写法来实现）
[@中断写法]
#IF
CHECKLEVELEX < 50
#SAY
你的等级不足50级\\
<离开[url=]/@exit[/url]>
#ACT
break
#IF
gender WOMAN
#ELSESAY
你不是女性玩家\\
<离开[url=]/@exit[/url]>
#ELSEACT
break
#IF
checkjob Warr
#ELSESAY
你不是战士职业\\
<离开[url=]/@exit[/url]>
#ELSEACT
break
#IF
CHECKGAMEGOLD > 49
#SAY
你满足条件，你的元宝有50个！\
你是女性，50级，战士职业玩家！\
<离开[url=]/@exit[/url]>
#ELSESAY
你的元宝不足50个\\
<离开[url=]/@exit[/url]>
//以上两种写法的执行结果一样，但从中可以看出使用break中断写法可以节省很多代码和不必要的跳转，能降低脚本在执行过程中的资源占用率。
break中断功能的作用就是，假设条件不成，就中断脚本继续执行，也就是break后面的脚本就不执行了，执行流程结束！第2种写法中，如果没有break，那么所有的判断都将按照从上到下的执行流程进行顺序执行，不管是否成立与否，都将一直执行到最后，大家可以把它取消了自己试试就知道了。
评论